Cách sử dụng Sparkline trong Google Sheets để trực quan hóa dữ liệu

Bạn có biết rằng mình có thể nhét toàn bộ biểu đồ vào trong một ô duy nhất trong Google Sheets không? Nó được gọi là Sparkline, và chỉ cần nhìn lướt qua là thấy ngay các mô hình dữ liệu của bạn. Nghe có vẻ không có gì đặc biệt, nhưng một khi bắt đầu sử dụng, bạn sẽ nhận ra sức mạnh của nó trong việc phát hiện xu hướng và giải thích dữ liệu một cách nhanh chóng.

Tại sao Sparklines của Google Sheets lại tốt đến vậy?

Biến số thành biểu đồ thu gọn

Về cơ bản, hàm SPARKLINE trong Google Sheets lấy một hàng số và biến chúng thành một biểu đồ nhỏ nằm gọn trong một ô duy nhất. Thay vì chèn một biểu đồ cỡ lớn chiếm hết nửa màn hình, bạn sẽ có một hình ảnh trực quan nhỏ gọn, tinh tế, cho thấy xu hướng chỉ trong nháy mắt.

Cú pháp cơ bản trông như sau:

=SPARKLINE(range)

Vì vậy, một công thức với một tập dữ liệu thực tế sẽ trông như sau:

=SPARKLINE(B2:F2)

Công thức này có thể cung cấp cho bạn một biểu đồ đường nhỏ gọn, gọn gàng về bất kỳ giá trị nào bạn có trong các ô từ B2 đến F2. Nếu theo dõi điểm kiểm tra của học sinh trong suốt học kỳ, bạn sẽ ngay lập tức thấy liệu điểm số của chúng đang tiến bộ, chững lại hay tụt dốc không phanh - tất cả mà không cần phải rời khỏi lưới số liệu.

Cách chèn biểu đồ thanh xếp chồng vào một ô

Đôi khi biểu đồ đường không phải là thứ bạn cần. Nếu bạn muốn so sánh các giá trị giữa nhiều danh mục - ví dụ, các phần khác nhau của bài kiểm tra như đọc hiểu, tóm tắt và từ vựng - một biểu đồ Sparkline dạng thanh xếp chồng hoạt động rất hiệu quả. Thay vì hiển thị tiến trình theo thời gian, nó cho thấy từng phần đóng góp vào tổng thể như thế nào.

Đây là cách thiết lập:

=SPARKLINE(B2:D2, {"charttype","bar"})

Thao tác này tạo ra một thanh nhỏ gọn ngay bên trong ô, với mỗi phân đoạn có kích thước tương ứng với giá trị của nó. Đây là một cách nhanh chóng để so sánh các thông số như số liệu hiệu suất nhân viên, phân bổ ngân sách hoặc phản hồi khảo sát mà không làm lộn xộn trang tính với các biểu đồ kích thước đầy đủ.

Tất nhiên, bạn không nhất thiết phải dừng lại ở mặc định:

=SPARKLINE(B2:D2,{"charttype","bar"; "max",80; "color1","blue"; "color2","black"; "color3","green"; "empty","ignore"; "rtl",false})

Trong công thức này, giá trị max đặt thang đo. Ở đây, thanh được giới hạn ở 80 điểm. Các đối số color1, color2 và color3 cho phép bạn gán màu cho từng phân đoạn. Bạn có thể thêm nhiều đối số màu hơn nếu có thêm nhiều danh mục. Đối số empty cho Sheets biết phải làm gì với các ô trống (ở đây, ví dụ sẽ bỏ qua chúng). Đối số rtl (right-to-left) kiểm soát thứ tự của các thanh. Đặt thành false sẽ giúp biểu đồ chạy tự nhiên từ trái sang phải.

Chèn biểu đồ Sparkline cột

Đôi khi, bạn muốn làm nổi bật các điểm cao và điểm thấp rõ ràng hơn. Đó là lúc cần đến biểu đồ Sparkline cột. Chúng hoàn hảo khi bạn xử lý các giá trị thay đổi nhiều, chẳng hạn như doanh thu hàng tháng, điểm kiểm tra hoặc số bước chân hàng ngày. Mỗi giá trị trong phạm vi sẽ trở thành một cột nhỏ riêng biệt, được xếp gọn gàng bên trong ô:

=SPARKLINE(B2:E2,{"charttype","column"})

Bằng cách này, bạn có thể ngay lập tức xem tháng nào có hiệu suất tốt nhất hoặc tháng nào có số liệu giảm. Có thể tiến xa hơn một bước bằng cách đặt một thang đo cố định và tạo cá tính cho các cột bằng màu sắc yêu thích hoặc màu thương hiệu:

=SPARKLINE(B2:E2,{"charttype","column";"ymin",50;"ymax",100;"color","purple"})

Trong trường hợp này, các cột được vẽ trong khoảng từ 50 đến 100, giúp việc so sánh trở nên nhất quán hơn, và màu tím làm cho biểu đồ nổi bật hơn.

Chèn biểu đồ Sparkline Win/Loss

Giờ đây, nếu dữ liệu của bạn là nhị phân (như mục tiêu đạt được so với mục tiêu không đạt được hoặc kết quả khảo sát có/không), biểu đồ Sparkline Win/Loss thậm chí còn hiệu quả hơn. Thay vì hiển thị độ lớn, nó chỉ đơn giản cho bạn biết mỗi sự kiện là win (dương) hay loss (âm). Đây là cú pháp cơ bản có thể sử dụng:

=SPARKLINE(B2:E2,{"charttype","winloss"})

Bất kỳ giá trị dương nào cũng sẽ hiển thị dưới dạng một thanh phía trên trục, trong khi các giá trị âm nằm bên dưới. Điều này giúp bạn dễ dàng quét nhanh các thành công và thiếu sót. Và giống như các Sparkline khác, bạn có thể tùy chỉnh thêm:

=SPARKLINE(B5:E5,{"charttype","winloss"; "color","blue"; "negcolor","red"; "nan","convert"; "axis",true})

Trong phiên bản này, win được tô màu xanh lam, loss được tô màu đỏ, các giá trị không phải số được coi là 0 (nhờ đối số nan), và một đường trục chạy qua biểu đồ để tăng thêm độ rõ ràng.